Schlagwort-Archive: asobjc

ASObjC: Bindings

Die Verknüpfungen von Variablen und Methoden über Verbindungen im Interface Builder sind schon eine feine Sache.

Über Bindings ist es nun möglich Interface Elemente automatisch mit Werten zu befüllen ohne eine einzelne Zeile Code zu schreiben.

Im Beispiel vorher unter Actions musste das NSTextField noch mit textField’s setStringValue_(„String“) befüllt werden.

asoc_binding_001

Unser Beispiel das auf den vorherigen Seiten zu finden ist wird nun erweitert. Im Fenster wird nun ein Label samt TextField hinzugefügt.

asoc_binding_002

Das Textfield wird nun ausgewählt. Im Inspector aktivieren wir nun den vierten Reiter mit den Bindings. Im obersten Abschnitt „Value“ setzen wir das Höckchen bei „Bind to:“ und wählen die entsprechende Klasse. In unserem Fall heisst diese „Controller“. Bei „Model Key Path“ muss dann der Name der Variablen eingetragen werden aus dem die Werte übernommen werden sollen.

[wpdm_file id=11]

ASObjC: Actions (aNotification)

Bis jetzt haben wir alles durch Outlets, Actions und Bindings. Nur was ist zu tun wenn zum Beispiel der User den Wert eines Textfeldes öndert und wir darauf reagieren wollen?

Im Prinzip kann dies mit einer Action geschehen. Nur wird diese nicht mit (sender) definiert, sondern mit (aNotification). Siehe Methode somethingsChanged_(aNotification).

-- controller.applescript
-- asoc_03

-- Created by Christian Sonntag on 11.04.10.
-- Copyright 2010 __MyCompanyName__. All rights reserved.

script controller
  property parent : class "NSObject"

  property |count| : 1

  --Outlet
  property textField : missing value
  property textFieldToChange : missing value

  --Action
  on doSomething_(sender)
    beep
    textField's setStringValue_("Hello World! (" & |count| & ")")
    set my |count| to (my |count|) + 1
  end doSomething_

  on somethingsChanged_(aNotification)
    set temp to textFieldToChange's stringValue()
    set temp to temp as string
    display alert "textField changed to: " & return & temp
  end somethingsChanged_

end script

asoc_notification_001

Wir erweitern nun wieder unser Beispiel um ein weiteres Label und ein Textfield.

asoc_notification_002

Wieder ziehen wir mit gedrückter rechten Maustaste vom NSObject Controller eine Verbindung zum neuen Textfeld.

asoc_notification_003

Nach dem loslassen der Maustaste wird wieder das kleine graue Fenster angezeigt. In diesem Fall wählen wir nun das Outlet „textfieldToChange“.

asoc_notification_004

Nun muss für die Notification eine Verbindung zur Klasse hergestellt werden. Vom Textfeld ausgehend wird nun mit gedrückter rechten Maustaste eine Verbindung zum NSObject Controller definiert.

asoc_notification_005

Wieder erscheint die Auswahl der vorhandenen Methoden und wir wählen „somethingsChanged“.

[wpdm_file id=12]

ASObjC: Actions (sender)

Actions sind der nächste Schritt um ASOC Programme zu schreiben. Outlets schaffen die Möglichkeit aus dem Programmcode auf UI Elemente zuzugreifen.

Actions im Gegenzug rufen Methoden auf die bei einem UI Ereignis z.B. ein Klick auf einen Button ausgelöst werden.

Diese werden wie folgt in der Klasse definiert:

-- controller.applescript
-- asoc_01

-- Created by Christian Sonntag on 11.04.10.
-- Copyright 2010 __MyCompanyName__. All rights reserved.

script controller
  property parent : class "NSObject"

  --Outlet
  property textField : missing value

  --Action
  on doSomething_(sender)
  end doSomething_

end script

asoc_action_001

So, ab in den Interface Builder. Aus der Library wird ein NSButton unserer Wahl ins Fenster gezogen, positioniert, angepasst und mit einem schönen Namen versehen.

asoc_action_002

Nun muss dem Button auch eine Action aus der Klasse zugewiesen werden. Mit gedrückter rechter Maustaste ziehen wir eine Verbindung von dem Controller Objekt auf den neu positionierten NSButton und lassen die rechte Maustaste los.

asoc_action_003

Auch hier erscheint wieder ein kleines schwarzes Fenster das alle vorhandenen Methoden aus der Klasse anzeigt. Hier wählen wir „doSomething“ aus.

asoc_action_004

Zum Abschluss kann alles natürlich noch mal geprüft werden. Bei ausgewähltem NSButton schauen wir nun im Inspector im vorletzten Reiter unter „Sent Actions“, und siehe da dort ist „doSomething“ zu sehen.

So jetzt hauchen wir dem ganzen noch etwas Leben ein, siehe unten. Denn nach dem kompilieren passiert nämlich gar nix. Als Beispiel lassen wir nun einen Warnton ausgeben, eine Variable wird hoch gezählen, die im Anschluss mit einem „Hello World!“ im NSTextField ausgegeben wird.

Fürs erste sind die wichtigsten Basics erklärt auf die man weiter aufbauen kann.

-- controller.applescript
-- asoc_01

-- Created by Christian Sonntag on 11.04.10.
-- Copyright 2010 __MyCompanyName__. All rights reserved.

script controller
  property parent : class "NSObject"

  property |count| : 1

  --Outlet
  property textField : missing value

  --Action
  on doSomething_(sender)
    beep
    textField's setStringValue_("Hello World! (" & |count| & ")")
    set my |count| to (my |count|) + 1
  end doSomething_

end script

[wpdm_file id=10]

ASObjC: Outlets

So bis jetzt haben wir nicht besonderes getan außer ein Projekt anzulegen und eine zusätzliche Klasse einzufügen.

Jetzt gehts los, wir beschäftigen wir uns nun mit Outlets. Outlets definieren innerhalb einer Klasse eine Variable die später im Interface Builder mit einem GUI Objekt verknüpft werden kann.

Der Vorteil dabei ist dass dieses GUI Objekt einfach über den Variablennamen angesprochen werden kann. Wer noch AppleScript Studio in Erinnerung hat kennt die umständliche Referenzierung auf ein GUI Element innerhalb des Codes.

-- controller.applescript
-- asoc_01

-- Created by Christian Sonntag on 11.04.10.
-- Copyright 2010 __MyCompanyName__. All rights reserved.

script controller
  property parent : class "NSObject"

  --Outlet
  property textField : missing value

end script

Ein Outlet muss auf missing value gesetzt werden. Aus ObjC Sicht beudetet das nil bzw. no object. Ist ein Outlet so definiert erscheint dieses im Interface Builder als ein Outlet und kann mit einem Interfaceelement verbunden werden.

asoc_outlet_002

So ein Outlet ist in der Klasse definiert. Wie geht es aber weiter? Zunächst muß die Datei MainMenu.xib geöffnet werden die automatisch mit dem Interface Builder geöffnet wird. Dies geschieht mit einem Doppelklick auf die Resource in XCode.

Ist der IB gestartet zieht man aus der Library ein NSObject in das MainMenu.xib Fenster.

asoc_outlet_003

Das NSObject ist jetzt aber noch neutral bzw. ohne Funktion. Nach einem Klick auf das neue NSObject öffnet man das Inspectorfenster und geht auf den letzten Reiter. Unter Class Identify wöhlt mann nun aus dem Dropdown Menü die neu angelegte Klasse mit dem Namen controller aus.

Das NSObject ist nun mit der controller.applescript Klasse verknüpft und kann dessen Outlets verwenden.

asoc_outlet_004

Als nächstes ziehen wir ein NSTextField in das Projektfenster. Nun haben wir ein Interfaceobjekt das mit dem Outlet aus der ASOC Klasse verbunden werden kann.

asoc_outlet_005

Zum verbinden ziehen wir bei gedrückten Rechtsklick von dem NSObject Controller eine Verbindung zu dem neu angelegten NSTextField.

asoc_outlet_006

Über dem NSTextField die Maustaste wieder loslassen. Interface Builder sind alle Outlets der verknüpften Klasse bekannt und zeigt diese in einem kleinen grauen Fenster an. Das gewünschte Outlet kann nun ausgewählt werden. Im Beispiel ist es das Outlet „textField“.

asoc_outlet_007

Outlets können natürlich auch nach der Verbindung kontrolliert werden. Dazu muss dass NSTextField ausgewählt werden. Im Inspectorfenster unter dem letzten Reiter wird bei Referencing Outlets die Verbindung angezeigt.

Das Outlet ist eingerichtet und auf das UI Objekt kann aus der ASOC Klasse heraus angesprochen werden. Hierfür stehen die entsprechenden Cocoa Methoden des Objekts zur Verfügung. Dazu sollte man sich aber ein bisschen mit der Developer Documentation auseinandersetzen.

ASObjC: Klasse einbinden

Beim letzten Punkt haben wir so lapidar eine neue Klasse in ein ASObjC Projekt hinzugefügt. Nur wie greift man dann auf diese zu? Um dies zu bewerkstelligen gibt es zwei verschiedene Möglichkeiten.

Instanzierung im Code

Mit der ersten Möglichkeit wird die benötigte Klasse programmatisch hinzugefügt. Hierzu wird im Header mit property test : class „test“ of current application die Klasse „includiert“. Um die Instanzierung der Klasse muss man sich dann selbst kümmern, siehe folgenden Beispielcode.

-- benötigte Klasse "includieren"
property test : class "test" of current application

script ClassTestAppDelegate
  property parent : class "NSObject"

  --
  --
  --

  on classTest_(sender)
    --Klasse instanzieren
    set myTest to test's alloc()'s init
    --auf Klassenmethode zugreifen
    set strFromClass to myTest's convertString_("Wandle mich um." as string)
    --Rückgabewert der Methode ausgeben
    display alert strFromClass
  end classTest_

  --
  --
  --

end script

Instanzierung über Interface Builder

Eine Klasse kann aber auch ohne eine Zeile Code zu schreiben instanziert werden. In diesem Fall wird mit property test : missing value ein Outlet für den Interface Builder definiert. Innerhalb des Interface Builders zieht man nun ein NSObject Icon in das IB Dokumentenfenster. Im Identity Inspector wird der Name der Klasse eingetragen der Instanziert werden soll. Zum Schluss muss das Outlet noch mit dem NSObject verbunden werden (siehe Screenshot).

Der Beispielcode sieht wie folgt aus.

script ClassTestAppDelegate
  property parent : class "NSObject"

  --Instanzierung der Klasse über Interface Builder
  property test : missing value

  --
  --
  --

  on classTest_(sender)
    --auf Klassenmethode zugreifen
    set strFromClass to test's convertString_("Wandle mich um.") as string
    --Rückgabewert der Methode ausgeben
    display alert strFromClass
  end classTest_

  --
  --
  --

end script

ASObjC: Klasse hinzufügen

Der erste Schritt war nicht schwer. Als nächsten kleinen Schritt fügen wir eine neue Klasse hinzu.

Im linken Bereich „Groups & Files“ des Projektbaumes legen wir mit einem Rechtsklick „Add > New File…“ eine neue AppleScriptObjC Klasse an.

Im nächsten Dialog wird „AppleScript class“ ausgewählt.

Im letzten Schritt wird noch der Dateiname angegeben. Benennen wir diesen einfach mal „controller.applescript“.

-- controller.applescript
-- asoc_01

-- Created by Christian Sonntag on 11.04.10.
-- Copyright 2010 __MyCompanyName__. All rights reserved.

script controller
  property parent : class "NSObject"

end script

So sieht nun eine AppleScriptObjC Klasse aus. Eigentlich unspektakulär, das einzige was aufföllt ist property parent : class „NSObject“.

Diese ASOC Klasse erbt alle Eigenschaften von NSObject. AppleScript Datentypen werden automatisch durch die ASOC-Bridge in Objective C Klassen konvertiert. Im umgekehrten Weg ist das nicht der Fall.

Werden Objective C Objekte an AppleScript zurückgegeben werden diese nicht in AS Datentypen umgewandelt. Dies hat den Vorteil dass dann weiterhin ObjC Methoden darauf angewendet werden können.

Update 26.07.2010: Unter Xcode 4 fehlt leider das ASObjC Template um eine Klasse anzulegen. Entweder man erstellt einen passende Datei von Hand, oder lädtsich ein Ersatztemnplate von www.macosxautomation.com.

ASObjC: Basic Xcode Projekt

So, wir fangen jetzt mal ganz sachte an und legen das erste AppleScriptObjC Projekt mit XCode an.

XCode starten, je nach Konfiguration erwartet einem das „Welcome to XCode“ Fenster und wir klicken auf „Create a new XCode project“. Falls nicht denke ich ist der Weg über Menü „File > New Project…“ nicht schwer zu finden.

Im folgenden Dialog wöhlt man unter Mac OS X > Application > Cocoa-AppleScript Application. Nach „Choose…“ wöhlt man noch den Namen der Application und den gewünschten Speicherort des Projekts.

Das Projekt ist angelegt. Zu sehen ist die Basis für eine ASOC Application. Auf den ersten Blick sieht dieses wie ein ganz normale Cocoa Application Projekt aus.

Die einzigen Resourcen die ein ASOC Projekt erahnen lassen sind das AppleScriptObjC.framework und die Datei „ProjektNameAppDelegate.applescript„. In dieser sind die beiden Methoden applicationWillFinishLaunching_ undapplicationShouldTerminate_, die beim Start oder beim beenden einer ASOC Application ausgeführt werden.

Das war es fürs erste. Das Projekt kann kompiliert und gestartet werden.

ASObjC: NSURLConnection – http get and post

--
--  pgURLAppDelegate.applescript
--  pgURL
--
--  Created by goodtime on 4/10/11.
--  Copyright 2011 NiceMac. All rights reserved.

-- demonstrates doing a GET or POST Request using NSURLConnection.  Runs in the Background (not in main thread)
-- contains no UI... might add one later, for now it just logs or displays alerts
-- see console log and feel free to change the URL
-- reference material: http://cocoawithlove.com/2008/09/cocoa-application-driven-by-http-data.html

script pgURLAppDelegate
    property parent : class "NSObject"
    property self : current application's pgURLAppDelegate -- should match the script delegate name above

    property myURL : "http://www.heise.de"  -- URL of your request
    property postMethod : "POST"  -- use POST for POST
    property myBody : ""  -- PUT YOUR POST MESSAGE HERE if trying to do a POST

    -- URL Request Encoding
    property myEncoding : NSUTF8StringEncoding of current application --code for UTF8

    property getMethod : "GET"  -- use GET for any other Requests
    property intermediateMsg : "" --  Text String returned from the request (may not be complete for long downloads)
    property entireMsg : "" --  All the Text String returned from the request

    on pgURL_(myURL, myBody, myMethod)
        -- String to NSURL
        tell class "NSURL" of current application
            set myURL to URLWithString_(myURL)
        end tell

        -- String 
        tell class "NSString" of current application
            set myBody to stringWithString_(myBody)
        end

        set myBody to myBody's dataUsingEncoding_(myEncoding)

        tell class "NSString" of current application
            set myMethod to myMethod
        end

        tell NSMutableURLRequest of current application
            set myRequest to requestWithURL_(myURL)
        end

        tell myRequest
            setHTTPMethod_(myMethod)
        end

        -- add the Message Body when sending a POST Method
        if myMethod = "POST" then
            tell myRequest
                setHTTPBody_(myBody)
            end
        end

        -- form the connection
        set myConnection to (((current application's class "NSURLConnection")'s alloc)'s initWithRequest_delegate_(myRequest, self))
    end

    -- handle the connection in the background (not in main thread)
    -- this is controlled by the next four threads
    on connection_didReceiveResponse_(myConnection, response)

        tell class "NSHTTPURLResponse" of current application
            set statusText to (localizedStringForStatusCode_(statusCode of response)) as text
            set statusCode to (statusCode of response) as string
        end

        -- if it fails to do anything, show what it didn't do here (the error)
        if statustext = "no error" then
            -- I am not really sure if this does anything or if it is reseting the returnData properly
            tell current application's returnData
                setLength_(0)
            end
            else
            display alert "HTTP Error: " & statusCode & return & "Error Message: " & statusText & "." 
        end
    end

    on connection_didReceiveData_(myConnection, returnData)

        -- convert Data returned to String (Don't ever forget how to do this, it is a pain when do forget)
        set my intermediateMsg to (((current application's class "NSString")'s alloc)'s initWithData_encoding_(returnData, current application's NSUTF8StringEncoding)) as string
        log "didReceivedData:"

        log intermediateMsg & return & return

        set my entireMsg to my entireMsg & intermediateMsg

    end

    on connection_didFailWithError_(myConnection,trpErr)
        -- display alert trpErr as string
        log trpErr

        set EM to ""
        try
            set newError to (NSLocalizedDescription of userInfo of (trpErr)) as string
                on error EM
            -- if AppleScript can't do this, so what else is wrong
            set errorMore to EM
        end

        display alert newError & return & return & errorMore
    end

    on connectionDidFinishLoading_(myConnection)
        log "connection Finished."

        -- here you can do what you want to do with the intermediateMsg
        log "here is your entire message returned:"
        log entireMsg

        log "end of line."
    end

    on applicationWillFinishLaunching_(aNotification)
        -- Insert code here to initialize your application before any files are opened 

        -- run the request here for demonstration purposes
        pgURL_(myURL, myBody, getMethod)

    end applicationWillFinishLaunching_

    on applicationShouldTerminate_(sender)
        -- Insert code here to do any housekeeping before your application quits 
        return current application's NSTerminateNow
    end applicationShouldTerminate_

end script

ASObjC: NSImage – open, crop and save image

--Cocoa crop
set srcImage to NSImage's alloc()'s initWithContentsOfFile_(picPath)
srcView's setImage_(srcImage)

set w to _width's stringValue() as string as number
set h to _height's stringValue() as string as number
set t to _top's stringValue() as string as number
set l to _left's stringValue() as string as number

set destImage to NSImage's alloc()'s initWithSize_({|width|:w, height:h})

set destRect to {|size|:{w, h}, origin:{0, 0}}
set srcRect to {|size|:{w, h}, origin:{l, t}}

destImage's lockFocus()
srcImage's drawInRect_fromRect_operation_fraction_(destRect, srcRect, current application's NSCompositeSourceOver, 1.0)
destImage's unlockFocus()

destView's setImage_(destImage)

--save as png
set theData to destImage's TIFFRepresentation()
set myNsBitmapImageRepObj to NSBitmapImageRep's imageRepWithData_(theData)
set myNewImageData to (myNsBitmapImageRepObj's representationUsingType_properties_(current application's NSPNGFileType, missing value))
if not (myNewImageData's writeToFile_atomically_(picPath, true)) as boolean then
    set messageText to "There was an error writing to file"
    display dialog messageText buttons {"Ok"}
end if